#!/bin/bash

perl -nE '
  # Read entire file
  do { local $/=undef; $_=<>; };

  # Iterate through all assignments to `ret` plus following 15 lines of code afterwards
  while (/\n.*\b(?:(?:ret\s+=\s+(?!\d|WT_))|WT_TRET|WT_WINCALL_RETRY)(?:.*\n){15}/g) {

    # Save match
    $x = $&;

    # Calculate current matched position
    my $pos = pos()-length($x);

    # Set the next position to search from
    pos() = $pos+1;

    # Calculate line and offset
    $line = 3+(()=substr($_,0,$pos)=~/\n/g);
    $off = $x =~ /^\n.*\bret = / ? ":".(length($&)-6) : "";

    # Skip if the assignment is within a conditional expression
    next if $x =~ /^\n.*\b(?:while|if|switch|for).*?\bret = /;

    # Cut the useful portion of code after assignment:
    # Either until the end of the current function of until the next assignment.
    ($m = $x) =~ s/^\n.*?\bret = //;
    $m =~ s/\n[}]\n.*$//s;
    $next_ret = $m =~ s/\bret = .*$//s;

    # Skip if `ret` is referenced or there is a goto to error handling.
    next if $m =~ /\b(?:ret|goto (?:err|done))\b/;

    # Skip if its a conditional branch and theres an assignment coming next - we will check the next one next.
    next if $next_ret && $m =~ /
        ^ [^{}]+
        (?:
            (?:
                (?: [}] \s+ )? \b else \b (?: \s+ [{] )?
            ) | (?:
                 \b (?: case | default ) \b
            )
        )
        [^{}]+ $
    /xs;

    # Output the line in the compiler format.
    say "$ARGV:$line$off:".($x =~ s/(?<=.)\n.*$//sr =~ s/^\n//r);
  }
' `find src -name \*.[ch]`